VB.Net XML文檔處理

可擴展標記語言(XML)是一種非常類似於HTML或SGML的標記語言。這是由萬維網聯盟推薦的，可作為開放標準提供。

.Net Framework中的System.Xml命名空間包含用於處理XML文檔的類。以下是System.Xml命名空間中的一些常用類。

XML解析器API

XML數據的兩個最基本和廣泛使用的API是：SAX和DOM介面。

• 簡單的XML(SAX)API：在這裏，只為感興趣的事件註冊回調，然後讓解析器繼續處理文檔。 當文檔很大或者記憶體有限制時，這是非常有用的，它在從磁片讀取檔時解析檔，整個檔永遠不會存儲在內存中。
• 文檔對象模型(DOM)API：這是萬維網聯盟的建議，其中整個檔被讀入記憶體並以分層(基於樹)的形式存儲以表示XML文檔的所有特徵。

當處理大檔時，SAX顯然不能像DOM那樣快速地處理資訊。另一方面，單獨使用DOM要佔用大量資源，特別是在很多小檔上使用的時候。

SAX是只讀的，而DOM允許更改XML檔。 由於這兩個不同的API相互補充，所以一般都將它們用於大型專案。

對於這裏所有的XML代碼示例，我們使用一個簡單的XML檔movies.xml作為輸入：

<?xml version="1.0"?>

<collection shelf="New Arrivals">
<movie title="Enemy Behind">
   <type>War, Thriller</type>
   <format>DVD</format>
   <year>2003</year>
   <rating>PG</rating>
   <stars>10</stars>
   <description>Talk about a US-Japan war</description>
</movie>
<movie title="Transformers">
   <type>Anime, Science Fiction</type>
   <format>DVD</format>
   <year>1989</year>
   <rating>R</rating>
   <stars>8</stars>
   <description>A schientific fiction</description>
</movie>
   <movie title="Trigun">
   <type>Anime, Action</type>
   <format>DVD</format>
   <episodes>4</episodes>
   <rating>PG</rating>
   <stars>10</stars>
   <description>Vash the Stampede!</description>
</movie>
<movie title="Ishtar">
   <type>Comedy</type>
   <format>VHS</format>
   <rating>PG</rating>
   <stars>2</stars>
   <description>Viewable boredom</description>
</movie>
</collection>

用SAX API解析XML

在SAX模型中，使用XmlReader和XmlWriter類來處理XML數據。XmlReader類用於以快速，只進和非緩存的方式讀取XML數據。它讀取一個XML文檔或一個流。

示例1

這個例子演示了從檔movies.xml中讀取XML數據。

• 在應用程式的bin\Debug檔夾中添加movies.xml檔。
• 在Form1.vb檔中導入System.Xml名稱空間。
• 在窗體中添加一個標籤，並將其文本更改為“電影列表”。
• 添加三個列表框和三個按鈕，以顯示來自xml檔的電影的標題，類型和描述。

設計的效果如下 -

使用代碼編輯器窗口添加下麵的代碼。參考代碼實現如下 -

Imports System.Xml
Public Class Form1

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        ' Set the caption bar text of the form.
        Me.Text = "SAX API讀取XML示例1 - xuhuhu.com"
    End Sub
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        ListBox1().Items.Clear()
        Dim xr As XmlReader = XmlReader.Create("movies.xml")
        Do While xr.Read()
            If xr.NodeType = XmlNodeType.Element AndAlso xr.Name = "movie" Then
                ListBox1.Items.Add(xr.GetAttribute(0))
            End If
        Loop
    End Sub
    Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
        ListBox2().Items.Clear()
        Dim xr As XmlReader = XmlReader.Create("movies.xml")
        Do While xr.Read()
            If xr.NodeType = XmlNodeType.Element AndAlso xr.Name = "type" Then
                ListBox2.Items.Add(xr.ReadElementString)
            Else
                xr.Read()
            End If
        Loop
    End Sub
    Private Sub Button3_Click(sender As Object, e As EventArgs) Handles Button3.Click
        ListBox3().Items.Clear()
        Dim xr As XmlReader = XmlReader.Create("movies.xml")
        Do While xr.Read()
            If xr.NodeType = XmlNodeType.Element AndAlso xr.Name = "description" Then
                ListBox3.Items.Add(xr.ReadElementString)
            Else
                xr.Read()
            End If
        Loop
    End Sub
End Class

使用Microsoft Visual Studio工具欄上的“開始”按鈕執行並運行上述代碼。 點擊按鈕將顯示檔的標題，類型和電影描述。

分別點擊下麵的幾個按鈕來加載movies.xml 檔中的對應內容 -

XmlWriter類用於將XML數據寫入流，檔或TextWriter對象。它也以只向前，非緩存的方式工作。

示例2

這個示例中是通過在運行時添加一些數據來創建一個XML檔。參考以下步驟：

• 在窗體中添加一個WebBrowser控件和一個按鈕(Button)控件。
• 將該按鈕的Text屬性更改為顯示作者檔。

在代碼編輯器中添加下麵的代碼 -

Imports System.Xml
Public Class Form1
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        ' Set the caption bar text of the form.
        Me.Text = "寫入XML檔 - xuhuhu.com"
    End Sub
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim xws As XmlWriterSettings = New XmlWriterSettings()
        xws.Indent = True
        xws.NewLineOnAttributes = True
        Dim xw As XmlWriter = XmlWriter.Create("authors.xml", xws)
        xw.WriteStartDocument()
        xw.WriteStartElement("Authors")
        xw.WriteStartElement("author")
        xw.WriteAttributeString("code", "1")
        xw.WriteElementString("fname", "Su")
        xw.WriteElementString("lname", "Max")
        xw.WriteEndElement()
        xw.WriteStartElement("author")
        xw.WriteAttributeString("code", "2")
        xw.WriteElementString("fname", "Paul")
        xw.WriteElementString("lname", "Sharma")
        xw.WriteEndElement()
        xw.WriteStartElement("author")
        xw.WriteAttributeString("code", "3")
        xw.WriteElementString("fname", "Anshuman")
        xw.WriteElementString("lname", "Curry")
        xw.WriteEndElement()
        xw.WriteStartElement("author")
        xw.WriteAttributeString("code", "4")
        xw.WriteElementString("fname", "張")
        xw.WriteElementString("lname", "愛玲")
        xw.WriteEndElement()
        xw.WriteStartElement("author")
        xw.WriteAttributeString("code", "5")
        xw.WriteElementString("fname", "蘇")
        xw.WriteElementString("lname", "琴")
        xw.WriteEndElement()
        xw.WriteEndElement()
        xw.WriteEndDocument()
        xw.Flush()
        xw.Close()
        WebBrowser1.Url = New Uri(AppDomain.CurrentDomain.BaseDirectory + "authors.xml")
    End Sub
End Class

使用Microsoft Visual Studio工具欄上的“開始”按鈕執行並運行上述代碼。 單擊顯示作者檔將在Web流覽器上顯示新創建的authors.xml檔。運行結果如下圖所示 -

點擊顯示作者檔內容，看到以下結果 -

用DOM API解析XML

根據文檔對象模型(DOM)，XML文檔由節點的節點和屬性組成。XmlDocument類用於實現.Net Framework的XML DOM解析器。 它還允許通過插入，刪除或更新文檔中的數據來修改現有的XML文檔。

以下是XmlDocument類的一些常用方法：

示例3

在這個例子中，將向xml文檔authors.xml中插入一些新節點，然後在列表框中顯示所有作者的名字。

參考以下步驟：

• 將authors.xml 檔添加到應用程式的 bin/Debug 檔夾中(如果已經編寫上示例2，那麼應該在示例2工程中生成了)
• 導入System.Xml名稱空間
• 在窗體中添加一個列表框和按鈕控件，並將按鈕控件的Text屬性設置為顯示作者。

使用代碼編輯器添加以下代碼。參考代碼實現 -

Imports System.Xml
Public Class Form1
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        ' Set the caption bar text of the form.
        Me.Text = "插入XML節點 - xuhuhu.com"
    End Sub
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        ListBox1.Items.Clear()
        Dim xd As XmlDocument = New XmlDocument()
        xd.Load("authors.xml")
        Dim newAuthor As XmlElement = xd.CreateElement("author")
        newAuthor.SetAttribute("code", "6")
        Dim fn As XmlElement = xd.CreateElement("fname")
        fn.InnerText = "李"
        newAuthor.AppendChild(fn)
        Dim ln As XmlElement = xd.CreateElement("lname")
        ln.InnerText = "安"
        newAuthor.AppendChild(ln)
        xd.DocumentElement.AppendChild(newAuthor)
        Dim tr As XmlTextWriter = New XmlTextWriter("movies.xml", Nothing)
        tr.Formatting = Formatting.Indented
        xd.WriteContentTo(tr)
        tr.Close()
        Dim nl As XmlNodeList = xd.GetElementsByTagName("lname")
        For Each node As XmlNode In nl
            ListBox1.Items.Add(node.InnerText)
        Next node
    End Sub
End Class

使用Microsoft Visual Studio工具欄上的“開始”按鈕執行並運行上述代碼。點擊顯示作者 按鈕將顯示所有作者的名字，包括在運行時添加的名字。

點擊按鈕後的效果如下所示 -